// basicnpc.txt
// A very simple, naive text. Creature attacks anything it hates nearby.
// Once it has won, it returns to its home.
// Memory Cells:
//   Cell 0 - How creature moves.
//     0 - If 0, wander randomly. 
//     1 - Stands still until a target appears.
//     2 - Completely immobile, even if target appears.
//   Cell 1,2 - Stuff done flag. If both 0, nothing. Otherwise when this 
//     is killed, set to 1. (Example: If cell 1 is 3 and cell 2 is 5, when
//     creature is killed, sets SDF(3,5) to 1.)
//   Cell 3 - Dialogue node to start with if talked to. if left at 0, this
//     character doesn't talk.

begincreaturescript;

variables;

short i,target,bmessage;

body;

beginstate INIT_STATE;
	if (get_memory_cell(0) == 2)
		set_mobility(ME,0);
	break;

beginstate DEAD_STATE;

	reset_dialog();
	add_dialog_str(0,"_Gah!  No...  This!  I cannot die here._",0);
	add_dialog_str(1,"You did it.  General Luthair is dead.",0);
	add_dialog_str(2,"_No!  Why...  Sabertooth, did he want me to die?  Is that why he brought me here from Kalzas!_",0);
	add_dialog_str(3,"Luthair, from Kalzas?  Such a thing is not possible.  You know all of the Generals in Kalzas, and he is not one.",0);
	add_dialog_str(4,"_Nggh...  If you escape, tell the people in Rayguard Province...  That Duke Eubans has just died.  Tell them also...  that..._  He expires.",0);
	if(get_flag(99,0) == 1)
		add_dialog_str(5,"So...  This is Duke Eubans.  Was he lured by Sabertooth to come here?  That poor fool.",0);
	if(get_flag(99,0) == 2)
		add_dialog_str(5,"So...  This is Duke Eubans.  Casimir, Zenbu...  You poor, poor fool.  All of your guilt you had from abandoning this man was but an exercise in cruel coincidence.",0);
	bmessage = run_dialog(1);

	set_terrain(29,25,31);
	set_terrain(29,26,31);
	set_terrain(29,27,31);
	force_instant_terrain_redraw();
	play_sound(99);
	pause(5);

	message_dialog("So...  Sabertooth was expecting you to defeat this stooge as well.  How convenient.","The gates are open to the east.  He must be waiting for you.");

break;

beginstate START_STATE; 
	// if I have a target for some reason, go attack it
	if (target_ok()) {
		if (dist_to_char(get_target()) <= 16)
			set_state(3);
			else set_target(ME,-1);
		}
	
	// Look for a target, attack it if visible
	if (select_target(ME,8,0)) {
		do_attack();
		set_state(3);
		}
		
	// Have I been hit? Strike back!
	if (who_hit_me() >= 0) {
		set_target(ME,who_hit_me());
		do_attack();
		set_state(3);
		}
		
	// Otherwise, just peacefully move around. Go back to start, if I'm too far
	// from where I started.
	if ((my_dist_from_start() >= 6) || ((my_dist_from_start() > 0) && (get_memory_cell(0) > 0))) {
		if (get_ran(1,1,100) < 40) 
			return_to_start(ME,1);
		}
		else if (get_memory_cell(0) == 0) {
			fidget(ME,25);
			}

	// if we're in combat and the above didn't give me anything to do, just
	// stop now. Otherwise, game will keep running script, and that eats up CPU time.
	if (am_i_doing_action() == FALSE)
		end_combat_turn();
break;

beginstate 3; // attacking
	if (target_ok() == FALSE)
		set_state(START_STATE);
	do_attack();
break;

beginstate TALKING_STATE;
	if (get_memory_cell(3) == 0) {
		print_str("Talking: It doesn't respond.");
		end();
		}
	begin_talk_mode(get_memory_cell(3));
break;